Newest KB Articles in Tutorials

SFTP Client with Host-key Repository

Tue, 26 Apr 2022 15:47:01 GMT

This Delphi app implements a simple host key repository that keeps all known and verified by user SFTP host-keys and automatically accepts connections to these hosts.

Download Source Code

The SFTP Component provides all necessary remote host information through the OnVerifyServer event: host name, key type, finger-print, and host-key bytes. You can save this information, e.g. as a string to the TStringList object in your program. This allows you to easily save the string list content to the disk, and load the list next time you run the app.

The program connects to an SFTP host via the Secure Shell protocol (SSH), authorizes with the user/password or the Public Key algorithms, lists, downloads, and uploads files.

This program is mostly a simple demos, and by no means, a complete application. You are free to use it as a starting point to develop your own functionality.

How to Override Default POP3 Server Command Handlers

Mon, 18 Apr 2022 20:43:31 GMT

The program provides a Delphi tutorial that utilizes the Clever POP3 Server component together with the POP3 File Handler component to deliver Emails to clients from your own application.

Download Source Code

The TclPop3Server component represents a fully functional multithreaded server with the ability to customize the user and thread performance settings. The server supports all POP3 extensions, according to the RFC 1939, RFC 1734, and RFC 2449 protocols.

The other component, TclPop3FileHandler, implements the file-based storage for the user mailboxes and messages on the disk.

The given example shows how to override the default POP3 command handlers and implement your own ones. Please check out the STAT and the LIST overrides. Comments within the source code will help you to understand how the code works.

This program is mostly a simple demos, and by no means, a complete application. It has one predefined user, "CleverTester", with the password "clevertester". You are free to add any number of desired users using the TclPop3Server.UserAccounts property. The server supports both the POP and SASL authorization methods: LOGIN, CRAM-MD5, NTLM, and Kerberos.

Send Photo using Telegram Bot API

Mon, 11 Apr 2022 09:41:21 GMT

The program represents a Delphi tutorial that utilizes the Clever HTTP and HttpRequest components to submit an image to a Telegram channel using Telegram Bot API

Download Source Code

This Delphi program represents a mostly simple demos and by no means, a complete application. It's intended to demonstrate how to use the HTTP Client together with the HTTP Request component in your Delphi application.

The program allows you to load an image using the TImage VCL component, save the image source in to a stream, and substitute the derived stream to the REST API request using the OnLoadData event of the HTTP Request component.

The Clever HTTP components completely support SSL/TLS, custom HTTP headers, Form Field, JSON, and SOAP requests. The following example shows how to send JSON data to a REST service: How to write a REST client with JSON in Delphi

How to compile:

Please clone the GitHub/CleverComponents/Clever-Internet-Suite-Tutorials repository.
Download and install the Clever Internet Suite library.
Open and compile the SendTelegramPhoto.dproj project in your Delphi IDE.
Enjoy.

Please feel free to Contact Us and ask any program related questions.

Keep updated on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

How to Recompose Received MailMessage with Attachments

Mon, 11 Apr 2022 09:29:43 GMT

The program represents a Delphi tutorial that utilizes the Clever Mail Message and S/MIME Message components to parse / compose E-mail messages in MIME format, with file or image attachments.

Download Source Code

When using the TclMailMessage component together with the POP3 or IMAP4 clients, the message parts are extracted and saved to the MailMessage members. If you save the message source with the TclMailMessage.SaveMessage method or access the message source via the TclMailMessage.MessageSource property, the message is recomposed. Since the attachmets are not stored in memory, the component raises the OnLoadAttachment event in order to get a stream with the attachment content. As a result, you will not get the original message content. If you want to get the origital source of the received message, please use the TclPop3.Response (TclImap4.Response) property instead. Otherwise, you will have to implement both the TclMailMessage.OnSaveAttachment and TclMailMessage.OnLoadAttachment event handers. This is necessary to save emails with attachments, and the given program shows you how to do this.

The other component, TclSMimeMessage, represents the TclMailMessage descendant and provides an additional functionality to encrypt/decrypt and sign/verify the message using the S/MIME standard.

The given program utilizes both these components and additionally allows saving digitally verified message source. Comments within the source code will help you to understand how the code works.

Using this tutorial as a starting point, you can implement your own storage for the attached files and images, including database tables and in-memory streams.

See also:

How to compile:

Please clone the GitHub/CleverComponents/Clever-Internet-Suite-Tutorials repository.
Download and install the Clever Internet Suite library.
Open and compile the RecomposeMailMessage.dproj project in your Delphi IDE.
Enjoy.

Please feel free to Contact Us and ask any program related questions.

Keep updated on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

Silent Socket Receiver in Delphi

Wed, 26 Jan 2022 11:14:43 GMT

The tutorial represents a Delphi program that starts listening to an incoming connection, accepts the connection, receives all data over the established connection, and sends no data back to the client.

Download Source Code

This Delphi program represents a mostly simple demos and by no means, a complete application. It's intended to demonstrate how to use the TcpServerConnection socket class from the Clever Internet Suite library to start listening on the specified local port and receive TCP packets over the Network.

This functionality might be useful when you debug a Network app and want to analyze the produced TCP traffic. You can run the Silent Socket Receiver app and capture the Network packets between the client and the server, e.g. using the Wireshark utility. In this case your Network app acts as the client, and the Silent Socket Receiver app as the server.

You can even modify the Silent Socket Receiver program to send TCP response back to the connected client.

procedure TForm1.FormCreate(Sender: TObject);
begin
  StartupSocket();
  FConnection := TclTcpServerConnection.Create();
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FConnection.Free();
  CleanupSocket();
end;

procedure TForm1.btnListenClick(Sender: TObject);
var
  data: TStream;
begin
  try
    FConnection.NetworkStream := TclNetworkStream.Create();
    FConnection.Listen(StrToInt(edtPort.Text));

    memLog.Lines.Add('=== Start listening ===');
    FStarted := True;

    FConnection.TimeOut := -1;
    FConnection.Accept();

    data := TMemoryStream.Create();
    try
      repeat
        FConnection.ReadData(data);
        memLog.Lines.Add('Received bytes: ' + IntToStr(data.Size));
        Application.ProcessMessages();
        data.Size := 0;
      until not FConnection.Active;
    finally
      data.Free();
    end;

  except
    on E: EclSocketError do
    begin
      if ((E.ErrorCode <> 10053) and (E.ErrorCode <> 10038)) then raise;
    end;
  end;
end;

See also:

How to compile:

Please clone the GitHub/CleverComponents/Clever-Internet-Suite-Tutorials repository.
Download and install the Clever Internet Suite library.
Open and compile the SilentSocketReceiver project in your Delphi IDE.
Enjoy.

Have questions?

Please feel free to Contact Us

Join us on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

Mail Send with TMS FNC RichEditor

Tue, 14 Dec 2021 17:18:15 GMT

The program represents a Delphi tutorial that utilizes the TMS FNC UI RichEditor and Clever SMTP components to compose and send HTML E-mails.

Download Source Code

This Delphi program represents a mostly simple demos and by no means, a complete application. It's intended to demonstrate how to use the SMTP component together with the TMS FNC UI RichEditor in your Delphi application. Additionally, the program uses the MailMessage component, which allows you to create E-mails in the MIME format, including message headers, text- and HTML bodies, file attachments, and embedded images. The HtmlParser component parses the HTML content, extracts embedded images, and produces a text-plain representation of the HTML message body.

The program allows you to authenticate using the username/password information. Also the SMTP component supports the OAUTH2.0, Digest, NTLM, and other SASL authentication methods. The SMTP client component completely supports the SSL/TLS mode, including the client certificate authorization and the server validation process.

See also:

How to compile:

Please clone the GitHub/CleverComponents/Clever-Internet-Suite-Tutorials repository.
Download and install the Clever Internet Suite library.
Download and install the TMS FNC UI Pack library.
Open and compile the MailSendTMSRichEditor project in your Delphi IDE.
Enjoy.

Have questions?

Please feel free to Contact Us

Join us on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

Connect Bitstamp API from Delphi

Wed, 13 Oct 2021 08:11:02 GMT

Download Source Code

This program represents a converted C++ example, which is published in the Bitstamp API documentation. The example shows how to authenticate at the Bitstamp REST service, fill necessary request fields, and make an API call.

const
  api_key = 'api_key';
  api_secret = 'api_key_secret';

function TForm1.GenerateNonce: string;
begin
  Result := TGuid.NewGuid().ToString().ToLower().Trim(['{', '}']);
end;

function TForm1.GenerateTimestamp: string;
var
  time_since_epoch: Comp;
begin
  time_since_epoch := TimeStampToMSecs(DateTimeToTimeStamp(LocalTimeToGlobalTime(Now())))
    - TimeStampToMSecs(DateTimeToTimeStamp(EncodeDate(1970, 1, 1)));
  Result := FloatToStr(time_since_epoch);
end;

function TForm1.GetPayload(const ARequestData: string): string;
begin
  Result := TclFormFieldEncoder.Encode(ARequestData, '');
end;

function TForm1.GetSignature(const ADataToSign: string): string;
var
  hash: TclHmacSha256;
  key, data: TBytes;
begin
  hash := TclHmacSha256.Create();
  try
    key := TclTranslator.GetBytes(api_secret, '');
    data := TclTranslator.GetBytes(ADataToSign, '');

    hash.Init(key, 0, Length(key));

    hash.Update(data, 0, Length(data));

    Result := BytesToHex(hash.Digest()).ToLower();
  finally
    hash.Free();
  end;
end;

procedure TForm1.btnSubmitClick(Sender: TObject);
var
  x_auth,
  x_auth_nonce,
  x_auth_timestamp,
  x_auth_version,
  content_type,
  payload,
  http_method,
  url_host,
  url_path,
  url_query,
  x_auth_signature: string;
  data_to_sign: TStringBuilder;
  url, response: string;
begin
  //http.ProxySettings.Server := '20.81.62.32';
  //http.ProxySettings.Port := 3128;

  x_auth := 'BITSTAMP ' + api_key;
  x_auth_nonce := GenerateNonce();
  x_auth_timestamp := GenerateTimestamp();
  x_auth_version := 'v2';
  content_type := 'application/x-www-form-urlencoded';
  payload := GetPayload('{offset:1}');
  http_method := 'POST';
  url_host := 'www.bitstamp.net';
  url_path := '/api/v2/user_transactions/';
  url_query := '';

  data_to_sign := TStringBuilder.Create();
  try
    data_to_sign.Append(x_auth);
    data_to_sign.Append(http_method);
    data_to_sign.Append(url_host);
    data_to_sign.Append(url_path);
    data_to_sign.Append(url_query);
    data_to_sign.Append(content_type);
    data_to_sign.Append(x_auth_nonce);
    data_to_sign.Append(x_auth_timestamp);
    data_to_sign.Append(x_auth_version);
    data_to_sign.Append(payload);

    x_auth_signature := GetSignature(data_to_sign.ToString());
  finally
    data_to_sign.Free();
  end;

  url := 'https://' + url_host + url_path + url_query;

  request.Clear();

  request.AddTextData(payload);

  request.Header.Accept := '';
  request.Header.AcceptEncoding := '';
  request.Header.ExtraFields.Add('X-Auth: ' + x_auth);
  request.Header.ExtraFields.Add('X-Auth-Signature: ' + x_auth_signature);
  request.Header.ExtraFields.Add('X-Auth-Nonce: ' + x_auth_nonce);
  request.Header.ExtraFields.Add('X-Auth-Timestamp: ' + x_auth_timestamp);
  request.Header.ExtraFields.Add('X-Auth-Version: ' + x_auth_version);
  request.Header.ContentType := content_type;

  http.SilentHTTP := True;
  response := http.Post(url, request);

  memResponse.Lines.Text := response;

  ShowMessage('Done');
end;

Have questions?

Join us on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

HttpServer - handling form-field requests

Wed, 28 Apr 2021 18:19:18 GMT

Download Source Code

The code below runs the HTTP server, accepts requests from connected users, and sends responses. If the request contains form-field data, the form fields are parsed and extracted.

procedure TForm1.clHttpServer1ReceiveRequest(Sender: TObject;
  AConnection: TclHttpUserConnection; const AMethod, AUri: string;
  AHeader: TclHttpRequestHeader; ABody: TStream);
var
  request: TclHttpRequest;
  user, password, response: string;
  field: TclFormFieldRequestItem;
begin
  request := TclHttpRequest.Create(nil);
  try
    //assign the request header
    request.Header := AHeader;

    //load and parse the request
    ABody.Position := 0;
    request.RequestStream := ABody;

    //extract the form fields
    field := request.FormFields['username'];
    if (field <> nil) then
    begin
      user := field.FieldValue;
    end;

    field := request.FormFields['password'];
    if (field <> nil) then
    begin
      password := field.FieldValue;
    end;

    //process the extracted fields and send a response
    response := '<html><body><p>The user logged in.</p></body></html>';
    (Sender as TclHttpServer).SendResponse(AConnection, 200, 'OK', response);
  finally
    request.Free();
  end;
end;

How to modify a subject line of the email within the raw .eml source

Wed, 28 Apr 2021 17:30:23 GMT

Download Source Code

The code below loads an email message from an .eml file, parses the MIME message header, extracts and replaces the subject line, and finally, sends the message using the SMTP component.
The other MIME header fields can be modified using the introduced approach.

var
  fieldList: TclMailHeaderFieldList;
  ind: Integer;
  subject: string;
begin
  //load a message in a raw format.
  clSmtp1.MailData.LoadFromFile('mailmessage.eml');

  //set up the TclSmtp component
  clSmtp1.Server := 'mail.example.com';
  clSmtp1.UserName := 'user';
  clSmtp1.Password := 'secret';

  //specify the desired character set and MIME encoding for the Subject header field
  fieldList := TclMailHeaderFieldList.Create('utf-8', cmQuotedPrintable, DefaultCharsPerLine);
  try
    //parse the mail header
    fieldList.Parse(0, clSmtp1.MailData);

    //get an index of the Subject field
    ind := fieldList.GetFieldIndex('Subject');

    //get the Subject field value
    subject := fieldList.GetDecodedFieldValue(ind);

    //modify the subject line
    subject := subject + ' modified...';

    //remove the subject field from the clSmtp1.MailData string list
    fieldList.RemoveField(ind);

    //add an updated subject line
    fieldList.AddEncodedField('Subject', subject);

    //starting from now, the clSmtp1.MailData property contains the updated Subject field
  finally
    fieldList.Free();
  end;

  //send the message
  clSmtp1.Send();
end;

Have questions?

Join us on Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com

Download TS files from video stream

Tue, 19 May 2020 10:24:07 GMT

The example shows how to download TS files from a video stream using the MultiDownloader component.

The code utilizes the Clever Internet Suite library.

Download Source Code

Watch on YouTube

The task of downloading and joining TS video streams consists of three steps:

1) discover a m3u8 playlist URL, download this URL, and extract all TS file links;
2) download all extracted TS file links.
3) prepare config files for the ffmpeg utility.

You can obtain an m3u8 URL using Firefox with the installed Stream Detector add-on. This add-on allows you to automatically extract all TS video links and copy them to the clipboard.

procedure TForm1.btnGetListClick(Sender: TObject);
var
  i, counter: Integer;
  item: TclDownLoadItem;
  list: TStrings;
  urlParser: TclUrlParser;
  s: String;
begin
  if (clMultiDownLoader1.IsBusy) then
  begin
    ShowMessage('The downloading is in progress');
    Exit;
  end;

  clDownLoader1.URL := edtM3U8Url.Text;
  clDownLoader1.LocalFile := 'downloadlist.m3u8';
  clDownLoader1.LocalFolder :=  edtSaveToFolder.Text;
  clDownLoader1.ThreadCount := 1;
  clDownLoader1.Start(False);

  clMultiDownLoader1.DownLoadList.Clear();

  list :=  TStringList.Create();
  urlParser := TclUrlParser.Create();
  try
    list.LineBreak := #10;
    list.LoadFromFile(clDownLoader1.LocalFile);

    counter := 1;
    for i := 0 to list.Count - 1 do
    begin
      s := list[i];
      if (s <> '') and (s[1] <> '#') and (Pos('.ts', s) > 0) then
      begin
        item := clMultiDownLoader1.DownLoadList.Add();

        urlParser.Parse(edtM3U8Url.Text, s);
        item.URL := urlParser.AbsoluteUri;
        item.LocalFile := Format('%d.ts', [counter]);
        Inc(counter);
      end;
    end;
  finally
    urlParser.Free();
    list.Free();
  end;

  if (clMultiDownLoader1.DownLoadList.Count > 0) then
  begin
    edtProgress.Text := Format('%d video files found', [clMultiDownLoader1.DownLoadList.Count]);
  end else
  begin
    ShowMessage(
    'The provided m3u8 file doesn''t contain video files, please choose another URL.');
  end;
end;

procedure TForm1.btnStartClick(Sender: TObject);
begin
  if (clMultiDownLoader1.IsBusy) then
  begin
    ShowMessage('The downloading is in progress');
    Exit;
  end;

  memLog.Lines.Clear();

  FSuccessful := 0;
  FFailed := 0;

  clMultiDownLoader1.MaxStartedItems := StrToInt(edtDownloadBy.Text);
  clMultiDownLoader1.InternetAgent := edtUserAgent.Text;
  clMultiDownLoader1.TryCount := StrToInt(edtTryCount.Text);
  clMultiDownLoader1.TimeOut := StrToInt(edtTimeout.Text);

  clMultiDownLoader1.LocalFolder := edtSaveToFolder.Text;

  clMultiDownLoader1.Start();
end;

procedure TForm1.btnStopClick(Sender: TObject);
begin
  clMultiDownLoader1.Stop();
end;

procedure TForm1.clMultiDownLoader1StatusChanged(Sender: TObject;
  Item: TclInternetItem; Status: TclProcessStatus);
begin
  case Status of
    psSuccess: Inc(FSuccessful);
    psFailed, psErrors, psTerminated:
    begin
      Inc(FFailed);
      memLog.Lines.Add(Item.URL);
    end;
  end;
  edtProgress.Text := Format('Downloading successful: %d, failed: %d', [FSuccessful, FFailed]);
end;

This program doesn't join downloaded TS files. You can do that using the ffmpeg open-source utility. The program prepares a list of downloaded files to join in one single TS stream file. Optionally, we can re-split this stream on separated parts.

procedure TForm1.btnPrepareListClick(Sender: TObject);
var
  list: TStrings;
  batch: Integer;
  item: TclDownLoadItem;
  i, counter: Integer;
begin
  list := TStringList.Create();
  try
    batch := clMultiDownLoader1.DownLoadList.Count div StrToInt(edtSplitOn.Text);
    counter := 1;
     for i := 0 to clMultiDownLoader1.DownLoadList.Count - 1 do
     begin
        item := clMultiDownLoader1.DownLoadList[i];
        list.Add('file ''' + ExtractFileName(item.LocalFile) + '''');
        if(list.Count = batch) then
        begin
          list.SaveToFile(AddTrailingBackSlash(edtSaveToFolder.Text) + 
          Format('list%d.txt', [counter]));
          list.Clear();
          Inc(counter);
        end;
     end;
     if(list.Count > 0) then
     begin
        list.SaveToFile(AddTrailingBackSlash(edtSaveToFolder.Text) + Format('list%d.txt', 
        [counter]));
     end;
  finally
    list.Free();
  end;
  ShowMessage('Done');
end;

Have questions?

Join us Facebook YouTube Twitter Telegram Newsletter

Kind regards
Clever Components team
www.CleverComponents.com